@echo off
echo ****************************************************************************** >%systemdrive%\MGTools\rezip.txt
echo *              ReZip.Bat - (c) 11/26/2006 By Chaslang                        * >>%systemdrive%\MGTools\rezip.txt
echo *         This version supports Win2K, XP, Vista and Win 7                   * >>%systemdrive%\MGTools\rezip.txt
echo * This batch file is used to rezip all log files into a new MGlogsR.zip file * >>%systemdrive%\MGTools\rezip.txt
echo * that is saved in the MGtools folder. It can be used when Ziping to the     * >>%systemdrive%\MGTools\rezip.txt
echo * root folder has been failing for some reason.                              * >>%systemdrive%\MGTools\rezip.txt
echo *    11/26/2012 Version 0.01 - First verion of ReZip.bat                     * >>%systemdrive%\MGTools\rezip.txt
echo ****************************************************************************** >>%systemdrive%\MGTools\rezip.txt
echo.
echo *    ReZip.bat    - 11/26/2012 Version 0.01                                  *>>%systemdrive%\MGTools\filelog.txt
echo ReZip.bat      - 11/26/2012 Version 0.01

if exist "%userprofile%\escritorio" ( 
                                      set dtname=escritorio
				      goto NT
				    )
if exist "%userprofile%\bureau"     (
                                      set dtname=bureau
				      goto NT
				    )
if exist "%userprofile%\plocha"     (
                                      set dtname=plocha
				      goto NT
				    )

if exist "%userprofile%\bureaublad" (
                                      set dtname=bureaublad
				      goto NT
				    )

if exist "%userprofile%\desktop"    (
                                      set dtname=Desktop
				      goto NT
				    )
:NT

For %%g in (
%systemdrive%\avenger.txt
%systemdrive%\MGTools\browserinf.txt
%systemdrive%\combofix.txt
%systemdrive%\MGTools\ffdata.txt
%systemdrive%\MGTools\filelog.txt
%systemdrive%\MGTools\GetUnKey.txt
%systemdrive%\MGTools\hijackthis.txt
%WinDir%\system32\drivers\etc\hosts
%userprofile%\%dtname%\MBRCheck_*txt
%systemdrive%\MGTools\miscinfo.txt
%systemdrive%\MGTools\miscinfo2.txt
%systemdrive%\MGTools\msrvlog.txt
%systemdrive%\MGTools\msrvstate.txt
%systemdrive%\MGTools\netinflong.txt
%systemdrive%\MGTools\netinfo.txt
%systemdrive%\MGTools\newfiles.txt
%systemdrive%\MGTools\nwktst.txt
%systemdrive%\MGTools\procdll.txt
%systemdrive%\MGTools\runkeys.txt
%systemdrive%\MGTools\srven.txt
%systemdrive%\MGTools\sysinfo.txt
%systemdrive%\MGTools\sysrest.txt
%systemdrive%\TDSSKiller.*txt
%systemdrive%\MGTools\UserInfo.txt
%systemdrive%\MGTools\winfiles.txt
%systemdrive%\MGTools\winsock.txt
%systemdrive%\MGTools\zafind.txt
) do    (
REM echo DBG:  g = "%%g"
REM echo.
		if exist %%g (
                        echo     Zipping %%g
                        %systemdrive%\MGtools\zip.exe -j "%systemdrive%\MGtools\MGlogsR.zip" "%%g" >nul
                        echo     Finished Zipping %%g
			echo Finished Zipping %%g >>%systemdrive%\MGTools\rezip.txt
		) else (		                
                        echo     %%g Not Found
			echo Cannot Zip %%g - file not found >>%systemdrive%\MGTools\rezip.txt
		)
)

if exist %systemdrive%\MGTools\rezip.txt (
    echo     Zipping %systemdrive%\MGTools\rezip.txt
    echo Zipping %systemdrive%\MGTools\rezip.txt >>%systemdrive%\MGTools\rezip.txt
    %systemdrive%\MGtools\zip.exe -j "%systemdrive%\MGtools\MGlogsR.zip" %systemdrive%\MGTools\rezip.txt >nul
    echo     Finished Zipping %systemdrive%\MGTools\rezip.txt
)		
echo.
echo.
echo *** ReZiping complete - Your log file is %systemdrive%\MGtools\MGlogsR.zip ***
echo.
echo     Hitting any key will close this command prompt window
pause
:end