Batch File Problem.

I have a batch file with 3 commands. The first 2 run but not the third one. Removing command one has commands 2 & 3 run exactly as required. I found a workaround - typing exit after the first 2 commands have run.
But I don't want any user input. How do I get all 3 commands to run?

Code:

@echo off
:: Run the System File Checker
%windir%\System32\cmd.exe /k sfc /scannow
:: Filter the CBS.log file & save the results to the Desktop
findstr /c:"[SR]" %windir%\Logs\CBS\CBS.log >"%userprofile%\Desktop\sfclogs.txt"
:: Close Command prompt & open the sfclogs.txt file in Notepad
start Notepad "%userprofile%\Desktop\sfclogs.txt"

 

Eldon

The /k option of cmd.exe is the culprit. Rather use option /c. But is there any special reason why you even invoke another cmd.exe process? What about a simple SFC /SCANNOW ?

 

I would like the System File Checker to run and then open the filtered results in Notepad.
This is not for me, but, hopefully, a simple solution for those who have Windows-related problems.

 

I'm afraid you didn't get what I tried to tell you There is no need to run SFC in another cmd.exe process. So just write SFC /SCANNOW as 3rd line in your batch script.

Code:

@echo off
:: Run the System File Checker
sfc /scannow
:: Filter the CBS.log file & save the results to the Desktop
findstr /c:"[SR]" %windir%\Logs\CBS\CBS.log >"%userprofile%\Desktop\sfclogs.txt"
:: Close Command prompt & open the sfclogs.txt file in Notepad
start Notepad "%userprofile%\Desktop\sfclogs.txt"

 

Sorry about that, this is quite new to me and it's past 1 AM.
Will give it a run in the morning.
Thanks for your help.

 

Code:

@echo off
:: Check if the script was run elevated
>nul 2>&1 net session || (echo Run as Administrator!&pause&exit /b)
:: Run the System File Checker
sfc /scannow
:: Filter the CBS.log file & save the results to the Desktop
findstr /c:"[SR]" "%windir%\Logs\CBS\CBS.log" >"%userprofile%\Desktop\sfclogs.txt"
:: Close Command prompt & open the sfclogs.txt file in Notepad
start Notepad "%userprofile%\Desktop\sfclogs.txt"

 

Line 3 in your code doesn't work. I get the following (see image), I press a key and Command Prompt closes. It's not running hidden - I see no hard disk activity.



According to this link, to run the batch file elevated requires quite a bit of code.
http://www.winhelponline.com/blog/automatically-elevate-batch-file-run-administrator/

Removing lines 2 & 3 from your code and running the batch file as Administrator works perfectly.
I'm going to convert the .bat file to .exe and test it.

 

My intention was neither to run the file elevated nor to invoke the UAC prompt. It just should stop the script execution at that point if it wasn't run elevated. Otherwise SFC would fail but even then the text file would be created and opened in Notepad.
- If you want to run the script elevated without UAC prompt then you have to create a scheduled task with highest privileges and call it using SCHTASKS. Of course you need administrative permissions to create such a scheduled task. I don't think you want to do it that way.
- Invoking the UAC prompt is quite simple (even if you need at least a 2nd language):
*.bat

Code:

@if (@a)==(@b) @end /* :: Valid line in Batch an JScript to begin a JScript multi-line comment.

@echo off
:: Check if the script was run elevated. If not run the code again as JScript to invoke the UAC prompt and run as Administrator.
>nul 2>&1 net session || (
  cscript //nologo //e:jscript "%~fs0" "%~f0"
  exit /b
)
:: Run the System File Checker
sfc /scannow
:: Filter the CBS.log file & save the results to the Desktop
findstr /c:"[SR]" "%windir%\Logs\CBS\CBS.log" >"%userprofile%\Desktop\sfclogs.txt"
:: Close Command prompt & open the sfclogs.txt file in Notepad
start Notepad "%userprofile%\Desktop\sfclogs.txt"
exit /b
:: JScript:
*/ WScript.CreateObject('Shell.Application').ShellExecute('cmd.exe', '/c "' + WScript.Arguments(0) + '"', '', 'runas', 1);

 

Please NEVER do that. You can't predict the side effects. All those converters do is packing your batch script into some kind of self-extracting archive or installer. If you run the exe file it will extract your original batch code to somewhere in the %temp% folder and execute it.
- Those executables are often recognized as False Positives by antivirus software.
- Since the script will be executed in the %temp% folder and it gets another name it does not behave as you expect.
- Often the executable is a 32 bit application which causes the execution of your batch code in WOW64 mode on 64 bit Windows. Pathes may point to different directories (e.g. C:\Windows\System32 points to C:\Windows\SysWOW64).
- People think their code isn't visible. False! It's perfectly visible during runtime in the %temp% folder.

If you want to compile an executable then use a compilable language. Leave a Batch script a Batch script!

 

Thank you GermanOne, your help is much appreciated. I want to make it as easy as possible for those who are not computer literate - they don't know how to run an elevated Command Prompt, they leave out the space in sfc /scannow, etc.

I'm going to use the code in post #8.
Would that be a problem in Windows XP?

 

Happy 2018, Eldon!

Hybrid scripts like this run successfully on XP. JScript is the Windows implementation of ECMAScript (commonly known as JavaScript). It's also running as stand-alone in the Windows Script Host which is installed by default since Windows 2000. I don't expect any problems.

(Just in case you were wondering about my aversion to bat2exe tools - my experiences: https://www.dostips.com/forum/viewtopic.php?t=5908#p36858)

 

Wow!
Fortunately it all worked out in the end.

 

They should all so run on Windows 7 well too.

Just curious why you are trying to run these scripts.

 

Not sure what you referring to. The reason why to run SFC /SCANNOW should be quite clear. It finds and repairs corrupted system files.

If your question is why to run hybrid scripts then the answer is because Batch is only as good as the command tools that Windows has on board. Its scope is very limited. There are a lot of things that you can't do using pure Batch even if they could be done in the scripting languages of the Windows Script Host (like VBScript and JScript). In order to access all the objects and methods it's usual to write a temporary VBScript (like in the link that Eldon posted in #7) and call it from within the Batch code. The reason why I used JScript instead is that there is a little trick (first line in the script) to combine both Batch and JScript in the same file. There is no need to write a separate temporary file.

Nowadays you would rather use Powershell which has the full force of the .NET framework. But since Eldon wants to support XP (even if, in my humble opinion, we should immediately stop supporting this walking dead on a web site like MG) your best bet is still using Batch and the WSH.

 

I don't want/need to run this batch file.
There are numerous posts on MajorGeeks suggesting to run the System File Checker. And often people have problems - finding Command prompt, running it elevated, finding the CBS.log file if there are problems, etc.
Hopefully, this batch file is a simple all-in-one solution for those people.

 

Eldon, Niemiro from Sysnative.com did something similar some years ago. SFCFix produces a txt output which just shows the problems/missing, which are the exceptions, but not the rest of the forest. Its on the MG Files
http://www.majorgeeks.com/files/details/sfcfix.html

 

SFC well i new about this since DOS days.

I was asking about the batch file.I have tried some be for in power shell.And in command prompt but some of the batch file stuff never really worked for me.Im old school if you know what i mean.

 

StruldBrug, on the MajorGeeks's details page for SFCFix 3.0, I see this:

None of the above is necessary with my batch file.
Run it and wait for the sfclogs file to open in Notepad.

 

I just ran the batch file (Windows 7) and everything was completed exactly as I intended - in post #8, look at the Code after :: and my objective will be clear.

I will later test it on Windows XP .
Those running other versions of Windows... please try it and post your feedback.

PS I will send the file to the owners of MajorGeeks after the members input.

 

Ran ok on Win 10 x64 for me too. Only possible problems for noobies that I saw were Defender Smart Screen filter blocking it from running on my laptop, so needed to go through More Options to tell it to stop worrying and just run it, and UAC wanting confirmation to run it on my PC. I guess other security software might query it too. Good work

 

As with Earthling- On my did the same on myW10 x64 pro.
I tried just right click the file and run as administrator, and just got a do you want to install this little box, clicked ok - ran and posted text file perfectly.
Also just tried it on an XP VM, and the command box came up, and then I got a little box asking who was installing, and I tried that but the command box blipped off. I also tried it as administrator- no different.
I will have another go later (turn off antivirus etc,and let you know.

 

Ran it on 8.1. Success. I run as admin always with UAC set to never notify, but messages turn on for uac. I did get the 'publisher could not be verified' pop up.
And it found some things to fix,
The final line of the report said, "All files and registry keys listed have been successfully repaired."
So, Thank You!

Great Idea!
Good job!

 

I tried again in XP, but just second two as in first post- just pasted into command box, an it ran and gave a text file to desktop.
I tried the same way with the complete 3 commands (pasted in cmd box) and box blipped started , but shut off.
So last two commands would work for XP, if in a file as Eldon made for all three.......
Possibility that my setup (not original, and antivirus is kicking it) I will try tomorrow with all other stuff switched off and let you know.
A very useful idea, and well done Eldon.

 

@Eldon Please correct my typo in the first line.

Code:

@if (@a)==(@b) @end /* :: Valid line in both Batch and JScript to begin a JScript multi-line comment.

@Earthling @baklogic Executable files that you downloaded from the internet are always marked. You have to alow execution in the file properties before you run them. It may look like

or

depending on the Windows version. Just click / check "Unblock" and confirm with "OK".

My suggestion to Eldon is to provide the code at least packed into a zip file.

There is at least one issue that I'm aware. If an Update is pending then SFC /SCANNOW will abort. I'm not sure if I can fix this in a batch code but I'll think about it.

 

Done.

That's my intention.
I'll add a readme file with the Unblock info.
Any other info I should add?

 

Maybe that the script will fail if Windows updates are pending.

baklogic had some problems with the script on XP. I'm not sure what exactly was the reason (I only guessed). Were you already able to test on XP?

 

I'm running a little late.
I'll do it now and be back asap...

 

GermanOne -no, it was not blocked- I will try again later as I have to go out.
My XP VM is customized, and I have to look at what is there, and possibly, permissions, it seems.
I really appreciate your discussion, GermanOne, and Eldon.
I am too old to learn very much regarding batch files, and other coding, but you two are very clear in what you post - I can absorb a good deal, and I am sure it will help many who are interested.
Remembering may be a little different.............but, the mechanics of it do tend to stick

 

Thanks baklogic

@Eldon I suggest to begin the Batch code as follows

Code:

@if (@a)==(@b) @end /* :: Valid line in both Batch and JScript to begin a JScript multi-line comment.
@echo off
:: SFC will abort if Windows updates are pending. Prompt the user to install updates first.
if exist "%windir%\winsxs\pending.xml" (
  echo A Windows update is pending.
  echo Please install it first and reboot your computer.
  pause
  exit /b
)

 

I ran the batch file in Windows XP...
The Command Prompt window flashed for a split second, an empty sfclogs file opened in Notepad, and I was prompted to insert the Windows XP professional SP3 CD. I expected the latter.
After loading the disc, the Windows File Protection window opened and I wait about 30 minutes for it to complete and close. The empty sfclogs file on the Desktop was not replaced and the Logs folder in Windows was empty.

I am not wasting anytime to get this to work for Windows XP. Or Vista.

GermanOne, I'll edit the batch file.

 

I expect there was an error message that you were not able to see in such a short time. If you want to know what it was
- open a CMD window (press [Windows]+[R], type CMD, klick OK)
- drag & drop the batch file onto the Window
- hit Enter to run the script

 

That was more, or, less my experience, -I did find this on-line for XP...
"
For normal .Exe files you can get Run as Menu by pressing Shift + Rightclick. But this method does not work for .bat and .cmd files. So you have add that option by creating Registry file
Right click on Desktop
click on New
Then select Notepad
Now copy the code written below to this notepad file
Windows Registry Editor Version 5.00
[HKEY_CLASSES_ROOT\cmdfile\shell\runas\command] @="\"%1\" %*"
Now press "Ctrl + s" to save this file
save it with "Runas.reg" on desktop or other place you want
Now right click on "Runas.reg" file
click on "Merge"
I cannot remember where , now-
I tried it,but it apparently made the key(I had a little reg file icon on the resulting work) -
But , for, me, the problem seemed to be that I given the first options of-OPEN, AND EDIT .
Eldon - Great effort, though, and Thanks GermanOne

 

Good point baklogic! If you don't have a runas command specified for batch files you can't invoke the 'runas' verb in the JScript part. Maybe that's the culprit on XP. Unfortunately I can't remember if it was available on XP by default. It's too long ago ...
You may try the following code:

Code:

@echo off
:: File repair will abort if Windows updates are pending. Prompt the user to install updates first.
if exist "%windir%\winsxs\pending.xml" (
  echo A Windows update is pending.
  echo Please install it first and reboot your computer.
  pause
  exit /b
)
:: Add the runas command to Batch files
reg add "HKCR\batfile\shell\runas\command" /ve /t REG_EXPAND_SZ /d "%%SystemRoot%%\System32\cmd.exe /C \"%%1\" %%*" /f
:: Check if the script was run elevated. If not run the code again as JScript to invoke the UAC prompt and run as Administrator.
>nul 2>&1 net session || (
  cscript //nologo //e:jscript "%~fs0" "%~f0"
  exit /b
)
:: Run the System File Checker
sfc /scannow
:: Filter the CBS.log file & save the results to the Desktop
findstr /c:"[SR]" "%windir%\Logs\CBS\CBS.log" >"%userprofile%\Desktop\sfclogs.txt"
:: Close Command prompt & open the sfclogs.txt file in Notepad
start Notepad "%userprofile%\Desktop\sfclogs.txt"
exit /b
:: JScript:
*/ WScript.CreateObject('Shell.Application').ShellExecute('cmd.exe', '/c "' + WScript.Arguments(0) + '"', '', 'runas', 1);

 

Whoops sorry I left out the first line and I can't edit the post anymore. It was

Code:

@if (@a)==(@b) @end /* :: Valid line in both Batch and JScript to begin a JScript multi-line comment.

 

Thanks GermanOne for the additional code in post #34.
And thanks baklogic for the registry edit.
I have to restart to select the WinXP partition - be back asap.

 

I hope the registry update will work without elevated permissions on XP. Otherwise I'm afraid we're out of luck

 

It looks like we are out of luck.
I ran the latest batch file (post #34 and 35) and was faced with the same issues as described in post #31.
@GermanOne, should I remove lines 9 & 10 from the code?

@baklogic, your 'Runas.reg' file added the key but without Value data.
Putting @="\"%1\" %*" in the second line fixes it.

Code:

Windows Registry Editor Version 5.00

[HKEY_CLASSES_ROOT\cmdfile\shell\runas\command]
@="\"%1\" %*"

I also added this file to the registry.

Code:

Windows Registry Editor Version 5.00

[HKEY_CLASSES_ROOT\batfile\shell\runas\command]
@="\"%1\" %*"[/CODE}

 

Did you run the script from within a cmd window as I suggested in #32? Knowing the error messages does always help to debug the code.

If it doesn't work you should remove it.

 

Yes. There was no error message. The script ran as if the batch file was double-clicked.
My apology for not mentioning that.

Due to a prior commitment, I'll only be back much later today.

 

Eldon, I cannot take any credit for the code, as I was hunting for hints, or, answers, and found that code on-line ( I tried it, before copying the link to it, and lost the link, unfortunately), It might have been superuser , but I cannot find it again, at present.
As IN POST *24, I did test the second and third, (only by pasting code into the admin command window) perhaps making a version with just those two would suffice for XP ?- and maybe Vista.?
As it posts the report in desktop, I would think for the older systems that may be sufficient, and useful enough.
From my searches around, it seems that XP and 2000 never had registry entries needed for these sort of actions,

 

baklogic
Does this mean that SFC /SCANNOW will always work on XP even if not run elevated? If that is true it would be quite simple to implement a check into the code on what Windows version the script was run.

 

I am having problems with my version of XP, as RPC was turened off, and turning it on, and restarting did not fix it. (nlite customization , I believe)
I may try another install of XP VM , but cannot do it now (her indoors wants to go shopping)
When I tried sfc /scannow without admin, it said, as expected, that I must be admin to run . so it does need admin to run.
This may also be why I could not use the complete version of it, previously.
I did manage to see a quick bit before command window closed- something like "No program associated with it, go to folder and....." But right clicking for properties never helped, nor did not know what to carry on with.
As I said, and my nickname - I like to Tinker, but I am on very new ground with this.

 

sfc /scannow will run in an Administrator account in XP without needing any additional privileges. However it may - probably will require the installation CD at some point. Does in my pretty clean VM anyway.

 

There is still something that could be done. E.g. checking for the existence of the registry key, and if not prompt the user to import the .reg file or something like that. I'll assist but it's Eldon's idea and he has to decide

It's never too late to learn something new

What's your proposal how to go on?

 

Bearing in mind the intended audience of 'noobies', I would forget all about both XP and Vista. Eldon has already said
he doesn't intend wasting time on either and, having run sfc on both, that seems sensible to me. My sfc run on XP asked for the XP installation disk, which 9/10 XP users don't have. On Vista the sfc run (error free) did produce a sfc.log file in \Windows\System\Logs but when I go to read it in a Admin user account I get 'Access denied'. I would concentrate on Win 7 and later.

 

In that case we only could add a message in order to let the user know his OS isn't supported (rather than letting the script crash).

Code:

@if (@a)==(@b) @end /* :: Valid line in both Batch and JScript to begin a JScript multi-line comment.

@echo off &setlocal EnableExtensions DisableDelayedExpansion
:: Check the Windows version.
for /f "tokens=2 delims=[]" %%i in ('ver') do for /f "tokens=2,3 delims=. " %%j in ("%%i") do set /a "ver=%%j * 100 + %%k"
if %ver% lss 601 (
  echo The script does not support versions prior to Windows 7.
  pause
  exit /b
)
:: File repair will abort if Windows updates are pending. Prompt the user to install updates first.
if exist "%windir%\winsxs\pending.xml" (
  echo A Windows update is pending.
  echo Please install it first and reboot your computer.
  pause
  exit /b
)
:: Check if the script was run elevated. If not run the code again as JScript to invoke the UAC prompt and run as Administrator.
>nul 2>&1 net session || (
  cscript //nologo //e:jscript "%~fs0" "%~f0"
  exit /b
)
:: Run the System File Checker
sfc /scannow
:: Filter the CBS.log file & save the results to the Desktop
findstr /c:"[SR]" "%windir%\Logs\CBS\CBS.log" >"%userprofile%\Desktop\sfclogs.txt"
:: Close Command prompt & open the sfclogs.txt file in Notepad
start Notepad "%userprofile%\Desktop\sfclogs.txt"
exit /b
:: JScript:
*/ WScript.CreateObject('Shell.Application').ShellExecute('cmd.exe', '/c "' + WScript.Arguments(0) + '"', '', 'runas', 1);

 

No problem. While I have had the .reg file(s) for some time, I did find them at Winhelponline.com for those who want an 'official' source.
http://www.winhelponline.com/articl...tion-for-CMD-and-BAT-files-in-Windows-XP.html

I agree.
Those running WinXP (or WinVista) as their only OS, need to upgrade. And those who keep it around like it's a classic car (I'm guilty ), would just run the System File Checker at boot time.

It's now a team effort.
Any suggestions are welcome.

Thank you!

 

Right now I don't have any further suggestions Eldon.

 

Thank you for your invaluable help GermanOne.
I'll do a short Readme, zip the 2 files and submit it to the owners.